Jump to content
PLC Forum


andreacappellazzo

Controllo Di Tiro Svolgitore/avvolgitore

Recommended Posts

andreacappellazzo

Ho letto il prezioso tutorial di Livio scaricandolo dalla sezione didattica.Ho prelevato il file excel di esempio per il calcolo della coppia di tiro.Ottimo esempio che ho cercato di replicare in un altro file excel a titolo puramente didattico.Non riesco però a venire a capo della questione : in particolare per il calcolo della coppia di tiro trovo una formula dove compare il diametro anzichè il raggio dell' aspo...

Inoltre una volta calcolato la coppia totale che il motore deve impostare all'albero dell' aspo e ricavandone la corrente di tiro da imporre al motore, all' atto pratico se ho degli attriti meccanici nel sistema ( riduttore,supporti...) per un sistema Svolgitore dovrò sommare tale correnti di perdita o sottrarle ?

Link to comment
Share on other sites


Livio Orsini

Quel foglio di calcolo risale ad più di dieci anni fa.

Si imposta il diametro perchè è più comodo: di solito si da il diametro delle bobine (per gli svolgitori) o il diametro del mandrino (per gli avvolgitori). Tanto tra raggio e diametro c'è un fattore 2 :)

Gli attriti sono considerati nel rendimento della trasmissione; non sono considerati l'attrito di primo distacco e l'attrito dinamico dovuto alla ventilazione. Non è considerata la coppia di piegatura del materiale.

Il foglio di calcolo serve più che altro a dimensionare l'azionamento (motore più convertitore).

Comunque la coppia necesaria a vincere gli attriti si somma al tiro nel caso dell'avvolgitore, si sottrae nel caso di svolgitore.

Edited by Livio Orsini
Link to comment
Share on other sites

andreacappellazzo

grazie per l' esauriente e rapida risposta.Ho però ancora alcuni dubbi, forse è meglio descrivere dettagliatamente il mio problema.

In un controllo di Tiro di uno Svolgitore, nel sistema del PLC ho dei blocchi software dove eseguo le varie operazioni di calcolo. Parto dal calcolo della coppia di Tiro ( coppia tiro + coppia acc. su base momento inerzia ).Dal risultato, calcolo la corrente del motore necessaria a ottenere questa coppia sulla base dei dati di targa del motore stesso.A questo valore di corrente necessaria a mantenere il Tiro,sottraggo le correnti di perdita dovute agli attriti dei suppurti del mandrino ad esempio, successivamente correggo il risultato con un fattore di deflussaggio ( il motore in continua lavora in zona deflussata e quindi eseguio flux nominale/flux reale e ottengo un fattore con andamento parabolico al salire dei giri ).A questo punto in somma algebrica a tale corrente, si aggiunge l' uscita di un regolatore PI delle celle di carico che in questo caso dovrebbero eseguire una correzione "fine" del Tiro controllato (questa inserzione delle celle in modo "fine" dovrebbe compensare in qualche modo il calcolo matematico della coppia di tiro più o meno preciso o la deriva in caso di aumento/diminuzione degli attriti nel tempo ad esempio ) Il problema nasce dal momento che l' uscita del regolatore non si trova a ZERO o prossimo allo Zero durante la normale regolazione ma sempre "sbilanciata" a -30,-45 Kg di correzione e questo non me lo spiego....Significa che il calcolo della coppia a monte è sovradimensionato ? oppure commetto qualche errore di concetto nella filosofia di regolazione ?

Link to comment
Share on other sites

Livio Orsini

Gia è brutto lavorare in zona deflussata, complicarsi la vita in questo modo è un po' da masochisti :) .

Se hai la reazione da cella di carico, e ti ritrovi a dover correggere così tanto è chiaro che il feedforward è sbagliato.

Per capire più facilmente dove commetti l'errore dovresti analizzare la correzione in funzione del diametro. Io ho la sensazione dhe il problema tu l'abbia con il ricalcolo della coppia per il deflussaggio. Visto che in zona deflussata la potenza è costante la coppia decresce linearmente con il crescere della velocità. E' tanto vero che nei servodiametri, dove agisci sul limite di corrente, appena entri in zona deflussata non effettui più variazioni di corrente in funzione del diametro. In altri termini, al diminuire del diametro dovresti diminuire la corrente (per diminuire la coppia), però dovendo diminuire il flusso per aumentare la velocità lasci costante la corrente e hai la compesazione automatica del valore di coppia.

Link to comment
Share on other sites

andreacappellazzo

..al variare del diametro, fino a raggiungere il nocciolo del palo la correzione delle celle decresce e sembra in modo lineare.Riassumendo, inizialmente con diametro massimo l' uscita del pid si trova a -50 Kg ( su un Tiro impostato di 200 Kg) fino ad arrivare a +10Kg verso il palo. Il coefficiente di deflussaggio sembra che funzioni, apporta una correzione lineare al calcolo di Coppia all' aumentare dei giri (la coppia decresce con forma non lineare in zona deflussata ).

Il mio obbiettivo sarebbe quello di avere la correzione delle celle ( ossia l' uscita del pid delle celle che và in somma al calcolo di coppia del Tiro ) approssimativamente centrata a 0, al massimo +-5Kg per tutto lo svolgimento della bobina partendo da diametro max fino al minimo.

Ciò significherebbe avere un calcolo di coppia "perfetto" con tutte le compensazioni del caso.

uno spunto di riflessione arriva da un tuo suggerimento di applicare il feedforward...ma in quale modo ?

alcune informazioni

la larghezza della bobina è di 3,65 mt e il diametro iniziale-finale 2,2mt-0,36mt palo

tempo acc. 560 sec.

densità 0,75kgdm^3

velocità linea 1200mt/min

Link to comment
Share on other sites

Livio Orsini

Te lo chiedo solo ora perchè a me la cosa pare ovvia. Ma tu il feed forward di coppia lo ricalibri per il diametro? Da come si comporta la correzione sembra che o non esegui la ricalibrazione o la esegui in modo errato.

Ripeto devi avere un sistema identico ad un servo diametro a cui si somma la correzione da cella di carico.

Più che i dati di densità del materiale mi sarebbe d'aiuto conoscere i dati del motore: velocità di base e velocità equivalente al diametro mandrino (quello che chiami palo).

Nella zona a flusso costante devi decrescere il valore di feed forward di coppia, raggiunta la velocità base (cioè quando inizia il deflussaggio) il valore di feed forward deve rimanere costante.

Link to comment
Share on other sites

andreacappellazzo

...è in questo concetto di feed forward che ho dei dubbi...o almeno credo di non aver capito cosa intendi.

Per completezza di dati :

692 giri nominali a pieno campo con 400V e 200A di armatura

Rapporto di riduzione 4

probabilmente in giornata invio in allegato uno schemino di cosa ho realizzato..non riewsco a venire a capo della questione.

Link to comment
Share on other sites

Livio Orsini
è in questo concetto di feed forward che ho dei dubbi...

Pensa ad un servodiametro, che è ad un controllo di tiro ad anell aperto, cioè si imposta il valore di coppia (corrente) e si presume che corrisponda al tiro richiesto.

Nel caso di controllo ad anello chiuso, cioè con reazione da cella di carico come nel tuo caso, il feed forward corrisponde al valore di coppia di servodiametro.

Nel tuo caso hai il diametro iniziale apri a 2,2m quindi con 200kg di tiro sul materiale il motore dovrà generare una coppia pari a Cm=1,1m*200kg==> 220kg. Per comodità assumiamo che:

Kcm = 0,5kgm/1A da cui il tuo motore con 200A darà 100kgm di coppia.

n = rendimento della trasmissione (comprensivo di attriti) 0,92

Essendo uno svolgitore il rendimento viene a favore. Con diametro iniziale la velocità angolare del motore, alla massima velocità lineare, sarà:

w = 1200/(2.2*pi) ==>173,6rpm all'albero lento e 694,5 rpm all'albero motore. A questa velocità già si inzia a deflussare.

La coppia necessaria è stabilita in (220/4)*0,92=50,6 kgm

La costante di coppia a 594,5 rpm diventa ==>0,5*(692/694,5)=0,498kgm/1A quindi per ottenere il tiro previsto dovrai limitare la corrente del motore a 50,6/0,498=101,56A

Questo è il tuo valore di feedforward di corrente.

Durante l'operazione di svolgitura il diametro diminusce, ma contemporaneamente aumenta il deflussaggio con conseguente diminuzione proporzionale della costante di coppia. Se ti fai i conti ti accorgerai che i due fenomeni si compensano.

Pertanto il feedforward rimarrà costante per tutta l'escursione del diametro.

Le variazioni, con le conseguenti complicazioni, nascono nel momento in cui vai a lavorare con velocità minori della velocità nominale del motore, li devi ricalcolarti il limite di corrente ad ogni variazione di diametro.

Link to comment
Share on other sites

andreacappellazzo

Và bene, ho capito e chiarito il concetto nella mia testa.Il mio sistema rispecchia tutto ciò, compreso il feed forward. Nel dettaglio, il calcolo esegue totalmente quello da te descitto nel messaggio precedente !

L' unico aspetto che ho rivisto, ripeto forse con insistenza ,è stato quello di cambiare il rapporto tra giri reali e nominali sostituendolo con il rapporto flusso reale e nominale secondo caratteristica magnetica del motore.Questo perchè quando vado a ricalcolare la corrente di armatura necessaria a generare la coppia di Tiro,il rapporto dei giri è lineare invece il rapporto dei flussi è con andamento parabolico perchè la corrente è dipendente dal flusso del motore.Con tale andamento , il coefficiente riesce a "linearizzare" la risposta del controllo di Tiro durante tutto lo svolgimento della bobina invece prima con rapporto dei giri avevo un trend di Tiro con andamento parabolico verso fine bobina ( al palo ).Ancora, una volta calcolata questa corrente di armatura e adattata con tale coefficiente di flusso, sottraggo le correnti di attrito.

..probabilmente a questo punto mi viene da pensare a un errore logico di calcolo

// calcolo del volume rotolo totale - m^3

      L     "Supervision_Drive01".Hmi_Parms.MechanicalConfig.RollsDiameter
      L     1.000000e+003
      /R    
      T     #Diam                       // diametro in metri
      L     2.000000e+000
      /R    
      T     #Raggio                     // raggio in metri
      L     #Raggio
      *R    
      T     #Raggio_Quadrato            // raggi al quadrato

      L     #Diam
      L     #Diam
      *R    
      L     #PI_Greco
      *R    
      L     4.000000e+000
      /R    
      L     "Parametri_Svolgitori".Larghezza_Carta
      *R    
      L     1.000000e+003
      /R    
      T     "Unwinder_1_DB".Volume_Rotolo_Totale    // m^3

// Selezione diametro aspo ferro + calcolo del volume dell'aspo -m^3

      U     "Supervision_Custom".SelezionePalo
      SPB   m030
      L     "Supervision_Custom".Diam_Palo_Ferro
      SPA   m031
m030: NOP   0
      L     "Supervision_Custom".Diam_Palo_Gommato
m031: NOP   0
      L     1.000000e+003
      /R    
      T     #DiametroPaloSelezionato

      L     #DiametroPaloSelezionato
      L     #DiametroPaloSelezionato
      *R    
      L     #PI_Greco
      *R    
      L     4.000000e+000
      /R    
      L     "Parametri_Svolgitori".Larghezza_Carta
      *R    
      L     1.000000e+003
      /R    
      T     "Unwinder_1_DB".Volume_Aspo_ferro    // m^3

// calcolo del peso netto della carta partendo dall' inerzia carta - Kg

      L     #Diam
      L     #Diam
      *R    
      T     #Diam_Quadrato
      L     "Unwinder_1_DB".Inerzia_Rotolo_Carta
      L     #Diam_Quadrato
      /R    
      L     8.000000e+000
      *R    
      T     "Unwinder_1_DB".Peso_Carta  // Kg Carta

// calcolo del peso dell' aspo ferro - Kg   

      L     "Supervision_Custom".PesoPaloFerro
      T     "Unwinder_1_DB".Peso_Aspo_ferro    // Kg  Aspo

// calcolo dell'inerzia della carta [Jcarta] - Kgm^2

      L     #Diam
      L     #Diam
      *R    
      L     #Diam
      *R    
      L     #Diam
      *R    
      T     #Diam_Carta_esponente4

      L     #DiametroPaloSelezionato
      L     #DiametroPaloSelezionato
      *R    
      L     #DiametroPaloSelezionato
      *R    
      L     #DiametroPaloSelezionato
      *R    
      T     #Diam_Aspo_esponente4

      L     #Diam_Carta_esponente4
      L     #Diam_Aspo_esponente4
      -R    
      L     "Parametri_Svolgitori".Peso_Specifico_Carta    // peso specifico al m^3
      *R    
      L     "Parametri_Svolgitori".Larghezza_Carta
      *R    
      L     1.000000e+003
      /R    
      L     #PI_Greco
      *R    
      L     3.200000e+001
      /R    
      T     "Unwinder_1_DB".Inerzia_Rotolo_Carta

// calcolo dell'inerzia dell'Aspo P*D^2 / 8 [Jaspo] - Kgm^2
      L     #DiametroPaloSelezionato
      L     #DiametroPaloSelezionato
      *R    
      L     "Unwinder_1_DB".Peso_Aspo_ferro    // Kg
      *R    
      L     8.000000e+000
      /R    
      T     "Unwinder_1_DB".Inerzia_Aspo_ferro

// Inerzia Motore [Jmot] - Kgm^2  letta dai dati di targa

      L     "Unwinder_1_DB".Inerzia_Motore    // PD letto dai dati di targa del Motore
      L     #Riduttore_Quadrato
      *R    
      T     #JMotore_a_Rotolo

// Inerzia Totale Rotolo [Jtot]  = [Jcarta] + [Jaspo] + [JMotore] - Kgm^2

      L     "Unwinder_1_DB".Inerzia_Rotolo_Carta
      L     "Unwinder_1_DB".Inerzia_Aspo_ferro
      +R    
      L     #JMotore_a_Rotolo
      +R    
      T     "Unwinder_1_DB".Inerzia_Totale_Rotolo

// Calcolo del Tiro d'Inerzia C = T * r --> TJ = (Jtot*dv/dt)/Raggio^2 - Newton

      L     "Unwinder_1_DB".Inerzia_Totale_Rotolo
      L     "Unwinder_1_DB".Acc_Linea
      *R    
      L     #Raggio_Quadrato
      /R    
      L     -1.000000e+000              // dobbiamo togliere la coppia inerziale dalla coppia di tiro nelle dv/dt
      *R    
      T     "Unwinder_1_DB".Tiro_Inerzia_Newton
///////////////////////////////////////////////////////////////////////////////////////////////////////
// calcolo del fattore Fattore_K_Flusso per compensare la perdita di coppia nella zona di deflussaggio 
// Fattore_K_Flusso = Flusso_Nominale/Flusso_Attuale  
///////////////////////////////////////////////////////////////////////////////////////////////////////
      L     "Supervision_Drive01".Hmi_Status.SpeedFeedback_RPM
      L     5.000000e+002               // analisi sopra i 500 giri 
      >R    
      SPBN  M014
      L     "FB601_InstanceDB".SPDM.Drive.PPO_read.PZD10    // flusso attuale del motore
      L     0                           // test per valore coerente > 0
      >I    
      SPBN  M014

      L     1.310700e+004               // 13107 = valore del flusso pieno nominale - Standard SPDM
      L     "FB601_InstanceDB".SPDM.Drive.PPO_read.PZD10    // flusso attuale del motore
      ITD                               // conversione Word in Double Word
      DTR                               // conversione Double word in Real
      /R    
      T     "Unwinder_1_DB".Fattore_K_Flusso
      SPA   M015
M014: NOP   0
      L     1.000000e+000
      T     "Unwinder_1_DB".Fattore_K_Flusso
M015: NOP   0
//////////////////////////////////////////////////////////////////////////
// Calcolo delle perdite per attriti meccanici in Ampere sotto e sopra la velocità base a giri nominali
//////////////////////////////////////////////////////////////////////////
// differenza della Vel_Massima - Vel_Nominale
      L     2.286000e+003
      L     6.920000e+002
      -R    
      T     #Calc_vnominale_vmax
// differenza corrente alla Vel_Nominale - corrente a Vel_fix (velocità bassa)
      L     "Parametri_Svolgitori".Perdite_Giri_Nominali_U1
      L     "Parametri_Svolgitori".Perdite_Fisse_U1
      -R    
      T     #Perdite_vnominale_vfix
// differenza corrente alla Vel_Massima - corrente a Vel_Nominale
      L     "Parametri_Svolgitori".Perdite_Giri_Massimi_U1
      L     "Parametri_Svolgitori".Perdite_Giri_Nominali_U1
      -R    
      T     #Perdite_vmax_vnominale
// caso velocità reale > di Vel_Nominale
      L     "Supervision_Drive01".Hmi_Status.SpeedFeedback_RPM
      L     6.920000e+002
      >R    
      SPBN  M016
      L     "Supervision_Drive01".Hmi_Status.SpeedFeedback_RPM
      L     6.920000e+002
      -R    
      L     #Calc_vnominale_vmax
      /R    
      L     #Perdite_vmax_vnominale
      *R    
      L     "Parametri_Svolgitori".Perdite_Giri_Nominali_U1
      +R    
      T     "Unwinder_1_DB".Perdite_A
M016: NOP   0
// caso velocità reale < di Vel_Nominale
      L     "Supervision_Drive01".Hmi_Status.SpeedFeedback_RPM
      L     6.920000e+002
      <R    
      SPBN  M017
      L     "Supervision_Drive01".Hmi_Status.SpeedFeedback_RPM
      L     6.920000e+002
      /R    
      L     #Perdite_vnominale_vfix
      *R    
      L     "Parametri_Svolgitori".Perdite_Fisse_U1
      +R    
      T     "Unwinder_1_DB".Perdite_A
M017: NOP   0
////////////////////////////////////////////////////////////////////////
// Gestione dell' inserimento Regolazione "fine" Celle di carico U1-U2  30.01.2008
////////////////////////////////////////////////////////////////////////

      U(    
      L     "Supervision_Custom".Tiro_Regolato    //"TensRegData_Drive01".OUT.TensionFeedback
      L     "Parametri_Svolgitori".Tiro_Minimo_Aspi
      >=R   
      L     S5T#3S
      SE    "Ritardo_ins_Tiro"
      )     
      U(    
      L     "Supervision_Drive07".Hmi_Status.SpeedFeedback_Linear
      L     5.000000e+002
      >=R   
      )     
      =     "M101.2"                    // abilita inserimento Regolazione "fine"

      U     "M101.2"
      U     "Supervision_Drive01".Hmi_Parms.FunctionsEnable.TensionControlEnabled
      =     "M101.3"

      L     "Supervision_Custom".Rif_Tiro_Ramp_01    // Set tiro rampato Kg
      L     "TensRegData_Drive01".OUT.RegulatorOUTvalue    // uscita regolatore PI Tiro  +/- 20%
      +R    
      T     "Supervision_Custom".Tiro_Regolato

///////////////////////////////////////////////////////////////////////
// Gestione scambio di tiro tra SVO1 e SVO2 al Trasferimento
///////////////////////////////////////////////////////////////////////

      U     "Unwinder_Logica".Start_Trasf_Tiro
      SPBN  M025
      L     "Supervision_Custom".Tiro_Regolato
      L     "Supervision_Custom".Out_Rampa_Tiro
      -R    
      T     "Supervision_Custom".Tiro_Svolg_Primario
M025: NOP   0

      U     "Unwinder_Logica".End_Trasf_Tiro
      SPBN  M026
      L     0.000000e+000
      T     "Supervision_Custom".Tiro_Svolg_Primario
M026: NOP   0
      UN    "Unwinder_Logica".Start_Trasf_Tiro
      UN    "Unwinder_Logica".End_Trasf_Tiro
      SPBN  M027
      L     "Supervision_Custom".Tiro_Regolato
      T     "Supervision_Custom".Tiro_Svolg_Primario
M027: NOP   0

////////////////////////////////////////////////////////////////////////
// calcolo del tiro totale in Newton Tiro_Tot = Set_tiro + Tiro_Inerziale
////////////////////////////////////////////////////////////////////////

      L     "Supervision_Custom".Tiro_Svolg_Primario
      L     9.810000e+000
      *R    
      L     "Unwinder_1_DB".Tiro_Inerzia_Newton
      +R    
      T     "Unwinder_1_DB".Tiro_Totale_Newton

// seconda soluzione
/////////////////////////////////////////////////////////////////////////////////
// Calcolo della corrente di tiro attraverso la coppia C = T * r
// I_Tiro = C_mot / C_Nom * I_Nom
/////////////////////////////////////////////////////////////////////////////////
// calcolo della coppia nominale del motore : P = 80 Kw , I_Non = 200 A Rpm_Nom = 692
// C_Nom = P / ( Rpm_Nom/60 *2*#PI_Grec ) = 1103.96 Newton*metro

      L     "Unwinder_1_DB".Tiro_Totale_Newton
      L     #Raggio
      *R    
      L     "Supervision_Drive01".Hmi_Parms.MechanicalConfig.GearRatio
      /R    
      L     "Supervision_Custom".Rendimento_riduttore_SV1    // % 
      *R    
      L     1.000000e+002
      /R    
      T     "Unwinder_1_DB".Torque_Mot

// calcolo della corrente di tiro
      L     "Unwinder_1_DB".Torque_Mot
      L     "Supervision_Drive01".Hmi_Parms.CommunicationConfig.Current_Rated
      *R    
      L     1.103960e+003               // Coppia nominale ai giri nominali
      /R    
      L     "Unwinder_1_DB".Fattore_K_Flusso
      *R    
      L     "Unwinder_1_DB".Perdite_A   // somma delle perdite fisse
      +R    
      T     "Unwinder_1_DB".Corrente_Tiro

// controllo limiti  max +/-
      L     "Supervision_Drive01".Hmi_Parms.CommunicationConfig.Current_FULLSCALE
      NEGR  
      T     #Corrente_Max_Neg

      L     "Unwinder_1_DB".Corrente_Tiro
      L     "Supervision_Drive01".Hmi_Parms.CommunicationConfig.Current_FULLSCALE
      >R    
      SPBN  M023
      L     "Supervision_Drive01".Hmi_Parms.CommunicationConfig.Current_FULLSCALE
      T     "Unwinder_1_DB".Corrente_Tiro
M023: NOP   0

      L     "Supervision_Drive01".Hmi_Parms.CommunicationConfig.Current_FULLSCALE
      L     #Corrente_Max_Neg
      <R    
      SPBN  M022
      L     #Corrente_Max_Neg
      T     "Unwinder_1_DB".Corrente_Tiro
M022: NOP   0

Edited by Gabriele Riva
Inserito tag CODE
Link to comment
Share on other sites

Livio Orsini

Senza tante masturbazioni mentali.

FIno alla velocità nominale la coppia è costante, oltre la velocità nominale la potenza è costante. Dato che la potenza vale coppia * velocità angolare ne consegue che velocità angolare e coppia sono inversamente proporzionali e la proporzione è lineare.

Quindi dal momento che entri in regime di potenza costante, se non cambia il riferimento di tiro, al variare del diametro non deve cambiare la corrente di armatura per avere il medesimo valore di coppia. Questo in teoria, in pratica si effettuano piccole variazioni dovute ad imprecisioni ed a variazioni dei parassiti. A questo provvede l'anello di regolazione.

nei servodiametri a loop aperto, dove la precisione è minore, ci si basa su questo asunto. Ti assicuro che nel mondo, in questo momento, stanno lavorando migliaia di servodiametri con il principio che ti ho esposto.

Se vuoi capirne i fondamenti teorici analizza bene la macchina elettrica.

Link to comment
Share on other sites

andreacappellazzo

rispodo solamente adesso.Con i tuoi consigli ne sono uscito egregiamente dal problema.

E' stata una esperienza che mi è servita.

Se possibile,Livio mi servirebbe un parere / dei consigli a rigurado di un programmino che ho realizzato molto simile al tuo foglio excel per il calcolo delle coppie di Tiro ( diciamo che è quasi un clone, però riammodernato sopratutto nella grafica ).Spero di avere questa possibilità perchè il tuo contributo sarebbe ineguagliabile

Link to comment
Share on other sites

Livio Orsini

Mettilo on line, a disposizione degli utenti di PLCForum, così avrai numerosi pareri e suggerimenti e, magari, anche ringraziamenti :)

Link to comment
Share on other sites

andreacappellazzo

Sono d'accordo nel renderlo disponibile a tutti.Però prima della divulgazione Livio, ho necessità di un tuo parere personale e vorrei inviartelo.

Come posso spedirlo ?

Link to comment
Share on other sites

Livio Orsini

Ti ho mandato un MP con l'indirizzo email

Link to comment
Share on other sites

memphis

salve io ho un'applicazione simile ma il motore non viene deflussato.

In uscita agli svolgitori sono applicate celle di carico.

In tal caso come ricavo il feed forward di corrente?

grazie

Link to comment
Share on other sites

Livio Orsini

Stai parlando di un motore in cc, vero?

Se il motore lavora a flusso costante e saturo la coppia vale Cm = k * IA

k lo ricavi dividendo la coppia nominale del motore per il valore di corrente nominale.

Link to comment
Share on other sites

memphis

il motore è ac siemens 1750 giri 12,8A 35Nm 6,25Kw

Link to comment
Share on other sites

memphis

vorrei appunto calcolare un riferimento di corrente per il motore il più vicino possibile al tiro desiderato e poi correggere un 10% o 5% con il PID della cella.

velocità lineare max 20mt/min

diametro max bobina 1600mm

rapporto riduzione 300 circa

tiro max impostabile 100Kg

Link to comment
Share on other sites

Livio Orsini

Hai già tutti i dati per calcolarlo, basta fare una semplice divisione.

Se invece il problema tuo è relativo alla parte meccanica, leggi i miei tutorial sul dimensionamento dei motori (discussione in evidenza nella sezione motori e azionamenti), oppure quello sulle regolazioni (sezione didattica, sottosezione elettrotecnica)

Edited by Livio Orsini
Link to comment
Share on other sites

memphis

perdoni il ritardo delle mie risposte , ma durante il giorno sono in cantiere e posso connettermi solo la sera in hotel ........... si è vero ho già tutti i dati per ricavare il feed forward per la regolazione in corrente......... leggendo il tutorial ho letto la parte che riguarda la regolazione in velocità con celle di carico , come si può quantificare il"delta" che viene sommato o tolto al diametro di partenza ?

Link to comment
Share on other sites

Fabio Di Capua

Buongiorno a tutti, volevo chiedere un'informazione devo sistemare una confezionatrice verticale con svolgimento bobina posta sul lato posteriore della spalla dove sono posizionati ben 12 rulli di tensionamento film,per il controllo della velocità degli hz del motore viene utilizzato un potenziometro lineare collegato a un rullo con una corsa di salita di 22 cm, gli hz del motore per il fine scala  sono impostabili da pannello,il problema che ad oggi mi ritrovo  che dalla bobina nuova a quella vecchia devo cambiare sempre gli hz da pannello altrimenti con la bobina quasi vuota il potenziometro lineare tocca il fine asola del potenziometro lineare,volevo sapere se sapete consigliarmi su un corretto utilizzo dello svolgimento con potenziometro lineare posto verticalmente,grazie mille

Link to comment
Share on other sites

Livio Orsini

Non puoi accodarti ad un'altra discussione (non hai letto il regolamento che hai accettato?).

Inoltre questa è una discussione ferma da 10 anni.

 

Devi aprire una nuova discussione.

Link to comment
Share on other sites

Guest
This topic is now closed to further replies.


×
×
  • Create New...